Unicode Character Database

# Unicode NamesList File Format

Revision | 3.1
Authors | Asmus Freytag
Date | 2001-02-26
This Version | http://www.unicode.org/Public/3.1-Update/NamesList-2.html
Previous Version | http://www.unicode.org/Public/3.0-Update/NamesList-1.html
Latest Version | http://www.unicode.org/Public/UNIDATA/NamesList.html

###
Summary

> This file describes the format and contents of NamesList.txt

### Status

> The file and the files described herein are part of the Unicode Character Database (UCD) and are governed by the UCD Terms of Use stated at the end.

## 1.0 Introduction

The Unicode name list file NamesList.txt (also NamesList.lst) is a plain text file used to drive the layout of the character code charts in the Unicode Standard. The information in this file is a combination of several fields from the UnicodeData.txt and Blocks.txt files, together with additional annotations for many characters. This document describes the syntax rules for the file format, but also gives brief information on how each construct is rendered when laid out for the book. Some of the syntax elements were used in preparation of the drafts of the book and may not be present in the final, released form of the NamesList.txt file.

The same input file can be used to do the draft preparation for ISO/IEC 10646 (referred below as ISO-style). This necessitates the presence of some information in the name list file that is not needed (and in fact removed during parsing) for the Unicode book.

With access to the layout program (unibook.exe) it is a simple matter of creating name lists for the purpose of formatting working drafts containing proposed characters.

### 1.1 NamesList File Overview

The *.lst files are plain text files which in their most simple form look like this

@@<tab>0020<tab>BASIC LATIN<tab>007F
; this is a file comment (ignored)
0020<tab>SPACE
0021<tab>EXCLAMATION MARK
0022<tab>QUOTATION MARK
. . .
007F<tab>DELETE

The semicolon (as first character), @ and <tab> characters are used by the file syntax and must be provided as shown. Hexadecimal digits must be in UPPER CASE). A double @@ introduces a block header, with the title, and start and ending code of the block provided as shown.

For an ISO-style, minimal name list, only the NAME_LINE and BLOCKHEADER and their constituent syntax elements are needed.

The full syntax with all the options is provided in the following sections.

### 1.2 NamesList File Structure

This section gives defines the overall file structure

    NAMELIST:     TITLE_PAGE* BLOCK*

    TITLE_PAGE:   TITLE
    		| TITLE_PAGE SUBTITLE
    		| TITLE_PAGE SUBHEADER
    		| TITLE_PAGE IGNORED_LINE
    		| TITLE_PAGE EMPTY_LINE
    		| TITLE_PAGE COMMENTLINE
    		| TITLE_PAGE NOTICE
    		| TITLE_PAGE PAGEBREAK

    BLOCK:	      BLOCKHEADER
    		| BLOCK CHAR_ENTRY
    		| BLOCK SUBHEADER
    		| BLOCK NOTICE
    		| BLOCK EMPTY_LINE
    		| BLOCK IGNORED_LINE
    		| BLOCK PAGEBREAK

    CHAR_ENTRY:   NAME_LINE | RESERVED_LINE
    		| CHAR_ENTRY ALIAS_LINE
    		| CHAR_ENTRY COMMENT_LINE
    		| CHAR_ENTRY CROSS_REF
    		| CHAR_ENTRY DECOMPOSITION
    		| CHAR_ENTRY COMPAT_MAPPING
    		| CHAR_ENTRY IGNORED_LINE
    		| CHAR_ENTRY EMPTY_LINE
    		| CHAR_ENTRY NOTICE

In other words:
Neither TITLE nor SUBTITLE may occur after the first BLOCKHEADER.

Only TITLE, SUBTITLE, SUBHEADER, PAGEBREAK, COMMENT_LINE, and IGNORED_LINE may occur before the first BLOCKHEADER.

Directly following either a NAME_LINE or a RESERVED_LINE an uninterrupted sequence of the following lines may occur (in any order and repeated as often as needed): ALIAS_LINE, CROSS_REF, DECOMPOSITION, COMPAT_MAPPING, NOTICE, EMPTY_LINE and IGNORED_LINE.

Except for EMPTY_LINE, NOTICE and IGNORED_LINE, none of these lines may occur in any other place.

Note: A NOTICE displays differently depending on whether it follows a header or title or is part of a CHAR_ENTRY.

### 1.3 NamesList File Elements

This section provides the details of the syntax for the individual elements.

    ELEMENT		SYNTAX	// How rendered

    NAME_LINE:	CHAR <tab> LINE
    			// the CHAR and the corresponding image are echoed,
    			// followed by the name as given in LINE

    		CHAR TAB NAME COMMENT LF
    			// Names may have a comment, which is stripped off
    			// unless the file is parsed for an ISO style list

    RESERVED_LINE:	CHAR TAB <reserved>
    			// the CHAR is echoed followed by an icon for the
    			// reserved character and a fixed string e.g. <reserved>

    COMMMENT_LINE:	<tab> "*" SP EXPAND_LINE
    			// * is replaced by BULLET, output line as comment
    		<tab> EXPAND_LINE
    			// output line as comment

    ALIAS_LINE:	<tab> "=" SP LINE
    			// replace = by itself, output line as alias

    CROSS_REF:	<tab> "X" SP EXPAND_LINE
    			// X is replaced by a right arrow
    		<tab> "X" SP "(" STRING SP "-" SP CHAR ")"
    			// X is replaced by a right arrow
    			// the "(", "-", ")" are removed, the
    			// order of CHAR and STRING is reversed
    			// i.e. both inputs result in the same output

    IGNORED_LINE:	<tab> ";" EXPAND_LINE
    EMPTY_LINE:	LF
    			// empty lines and file comments are ignored

    DECOMPOSITION:	<tab> ":" EXPAND_LINE
    			// replace ':' by EQUIV, expand line into
    			// decomposition

    COMPAT_MAPPING:	<tab> "#" SP EXPAND_LINE
    			// replace '#' by APPROX, output line as mapping

    NOTICE:		"@+" <tab> LINE
    			// skip '@+', output text as notice
    		"@+" TAB * SP LINE
    			// skip '@', output text as notice
    			// "*" expands to a bullet character
    			// Notices following a character code apply to the
    			// character and are indented. Notices not following
    			// a character code apply to the page/block/column
    			// and are italicized, but not indented

    SUBTITLE:	"@@@+" <tab> LINE
    			// skip "@@@+", output text as subtitle

    SUBHEADER:	"@" <tab> LINE
    			// skip '@', output line as text as column header

    BLOCKHEADER:	"@@" <tab> BLOCKSTART <tab> BLOCKNAME <tab> BLOCKEND
    			// skip "@@", cause a page break and optional
    			// blank page, then output one or more charts
    			// followed by the list of character names.
    			// use BLOCKSTART and BLOCKEND to define the
    			// characters belonging to a block
    			// use blockname in page and table headers
    		"@@" <tab> BLOCKSTART <tab> BLOCKNAME COMMENT <tab> BLOCKEND
    			// if a comment is present it replaces the blockname
    			// when an ISO-style namelist is laid out

    BLOCKSTART:	CHAR	// first character position in block
    BLOCKEND:	CHAR	// last character position in block
    PAGE_BREAK:	"@@"	// insert a (column) break

    TITLE:		"@@@" <tab> LINE
    			// skip "@@@", output line as text
    			// Title is used in page headers

    EXPAND_LINE:	{CHAR | STRING}+ LF
    			// all instances of CHAR *) are replaced by
    			// CHAR NBSP x NBSP where x is the single Unicode
    			// character corresponding to char
    			// If character is combining, it is replaced with
    			// CHAR NBSP <circ> x NBSP where <circ> is the
    			// dotted circle

Notes:

- Blocks must be aligned on 16-code point boundary and contain an integer multiple of code points. The exception to that rule is for blocks of ideographs etc. for which no names are listed in the file. Such blocks must end on the actual last character.
- Blocks must be non-overlapping and in ascending order. Namelines must be in ascending order and following the block header for the block to which they belong.
- Reserved entries are optional, and will be supplied automatically. They are required whenever followed by ALIAS_LINE, COMMENT_LINE or CROSS_REF

### 1.4 NamesList File Primitives

The following are the primitives and terminals for the NamesList syntax.

    LINE:		STRING LF
    COMMENT:		"(" NAME ")"
    		"(" NAME ")" "*"
    BLOCKNAME:	<sequence of Latin-1 characters, except "(" and ")">
    NAME:	  	<sequence of uppercase ASCII letters, digit and hyphen>
    STRING:	  	<sequence of Latin-1 characters>
    CHAR:		X X X X
    		| X X X X X
    		| X X X X X X
    X:	  	"0"|"1"|"2"|"3"|"4"|"5"|"6"|"7"|"8"|"9"|"A"|"B"|"C"|"D"|"E"|"F"
    <tab>:	  	<sequence of one or more ASCII tab characters 0x09>
    SP:	  	<ASCII 0x20>
    LF:	  	<any sequence of ASCII 0x0A and 0x0D>

Notes:

- Special lookahead logic prevents a mention of a 4 digit standard, such as ISO 9999 from being misinterpreted as ISO CHAR. The - in a character range CHAR-CHAR is replaced by an EN DASH.
- Use of Latin-1 is supported in unibook.exe, but not portably, unless the file is encoded as UTF-16LE.
- The final LF in the file must be present
- A CHAR inside ' or " is expanded, but only its glyph image is printed, the code value is not echoed.
- Straight quotes in an EXPAND_LINE are replaced by curly quotes using English rules. Apostrophes are supported, but nested quotes are not.

## Modifications

Use of 4-6 digit hex notation is now supported.

## UCD Terms of Use

### Disclaimer

> The Unicode Character Database is provided as is by Unicode, Inc. No claims are made as to fitness for any particular purpose. No warranties of any kind are expressed or implied. The recipient agrees to determine applicability of information provided. If this file has been purchased on magnetic or optical media from Unicode, Inc., the sole remedy for any claim will be exchange of defective media within 90 days of receipt.

> This disclaimer is applicable for all other data files accompanying the Unicode Character Database, some of which have been compiled by the Unicode Consortium, and some of which have been supplied by other sources.

### Limitations on Rights to Redistribute This Data

> Recipient is granted the right to make copies in any form for internal distribution and to freely use the information supplied in the creation of products supporting the UnicodeTM Standard. The files in the Unicode Character Database can be redistributed to third parties or other organizations (whether for profit or not) as long as this notice and the disclaimer notice are retained. Information can be extracted from these files and used in documentation or programs, as long as there is an accompanying notice indicating the source.